Help:Extension:Phonos/QA/Wikidata

Wikidata Lexemes with forms which have IPA transcriptions which have a language property

SELECT ?lexemeId ?lemma ?word ?form
WHERE
{
  ?lexemeId wikibase:lemma ?lemma;
    ontolex:lexicalForm ?form.
  ?form ontolex:representation ?word.
  FILTER EXISTS {
    ?form p:P898 ?pronunciation.
    ?pronunciation pq:P407 ?lang.
  }
} LIMIT 10

Wikidata Item or Lexeme with pronunciation audio which have a language

SELECT ?item ?itemLabel ?statement ?o
WHERE 
{
  ?item p:P443 ?statement .
  ?statement pq:P407 ?o .
} limit 10

Wikidata Lexemes with forms which have pronunciation audio which has a language

SELECT ?lexemeId ?lemma ?word ?form
WHERE
{
  ?lexemeId wikibase:lemma ?lemma;
    ontolex:lexicalForm ?form.
  ?form ontolex:representation ?word.
  FILTER EXISTS {
    ?form p:P443 ?pronunciation.
    ?pronunciation pq:P407 ?lang.
  }
} LIMIT 10

Wikidata Items and Lexemes with pronunciation audio and IPA transcriptions

SELECT
  ?item ?itemLabel
  ?value ?valueLabel
  ?value1
WHERE 
{
  ?item wdt:P898 ?value .
  ?item wdt:P443 ?value1
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 10

Wikidata Items with IPA transcriptions which have a language

SELECT
  ?item ?itemLabel
  ?value ?valueLabel
  ?lang
WHERE 
{
  ?item p:P898 ?value .
  ?value pq:P407 ?lang
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 10

Number of languages per pronunciation audio for a Wikidata item

SELECT ?item ?statement (COUNT(?o) AS ?count)
WHERE 
{
  ?item p:P443 ?statement .
  ?statement pq:P407 ?o .
} GROUP BY ?item ?statement ORDER BY DESC(?count) LIMIT 10

Number of languages per pronunciation audio for a Wikidata Lexeme

SELECT ?lexemeId ?lemma ?form ?statement (COUNT(?o) AS ?count)
WHERE
{
  ?lexemeId wikibase:lemma ?lemma;
    ontolex:lexicalForm ?form.
  ?form p:P443 ?statement .
  ?statement pq:P407 ?o .
} GROUP BY ?lexemeId ?lemma ?form ?statement ORDER BY DESC(?count) LIMIT 10

Wikidata Lexemes with forms which have duplicate spellings

SELECT ?lexemeId ?lemma ?word (COUNT(?form) AS ?count)
WHERE
{
SELECT ?lexemeId ?lemma ?word ?form
WHERE
{
  ?lexemeId wikibase:lemma ?lemma;
    ontolex:lexicalForm ?form.
  ?form ontolex:representation ?word.
} LIMIT 1000
} GROUP BY ?lexemeId ?lemma ?word ORDER BY DESC(?count) LIMIT 10